10 HOME
20 PRINT CHR$(4);"PR#3"
30 DIM B(20,80)
32 DIM C(1510)
34 DIM D(7,7)
35 X1=10:Y1=42:BB=0:B=0

36 INVERSE:VTAB 1:HTAB 30:PRINT"MAZE PAINTER TOOL":VTAB 23:HTAB 1:PRINT"                                                                               ":VTAB 23:HTAB 26:PRINT"PRESS ANY KEY TO BE CONTINUE":VTAB 23:HTAB 55:GET Z$:NORMAL

37 HOME

38 INVERSE:VTAB 23:HTAB 1:PRINT" PLEASE INSERT A DATA DISK IN SLOT 6 DRIVE 2,THEN PRESS <SPC> TO BE CONTINUE. ":VTAB 23:HTAB 79:GET G$:VTAB 23:HTAB 79:PRINT G$:NORMAL:D2=1:GOSUB 15800

39 NORMAL:HOME


40 VTAB 10:HTAB 40:PRINT " "
45 VTAB 10:HTAB 40:PRINT "M"
50 INVERSE:VTAB 10:HTAB 42:PRINT "$":NORMAL
52 VTAB 20:HTAB 6:PRINT"Y":VTAB 20:HTAB 10:PRINT"I":VTAB 20:HTAB 15:PRINT"R - RUN":VTAB 20:HTAB 32:PRINT"S - SAVE MAZE":VTAB 20:HTAB 66:PRINT"DOLLAR :    0"
54 VTAB 21 :HTAB 5:PRINT"G H":VTAB 21:HTAB 9:PRINT"J K":VTAB 21:HTAB 15:PRINT"F - PAINTER":VTAB 21:HTAB 32:PRINT"L - LOAD MAZE":VTAB 21:HTAB 47:PRINT"X - CATALOG":VTAB 21:HTAB 66:PRINT"  STEP :    0"
56 VTAB 22 :HTAB 6:PRINT"B":VTAB 22:HTAB 10:PRINT"M":VTAB 22:HTAB 15:PRINT"Q - QUIT":VTAB 22:HTAB 32:PRINT"C - CLEAR SCN":VTAB 22:HTAB 66:PRINT"RESTEP :    0"

58 INVERSE:VTAB 23:HTAB 1:PRINT"                                                                               ":NORMAL
59 GOSUB 1200

60 R1=0:NO=0
62 VTAB 10:HTAB 40:PRINT"M":INVERSE:VTAB X1:HTAB Y1:PRINT "$":VTAB 23:HTAB 1:PRINT"COMMAND :                                                                     ":VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL
65 IF A$="Q" THEN 7000

66 IF A$=CHR$(25) THEN X2=X1-1:Y2=Y1:GOSUB 1000:GOSUB 29000:X1=X2:Y1=Y2
67 IF A$=CHR$(7) THEN X2=X1:Y2=Y1-1:GOSUB 1000:GOSUB 29000:X1=X2:Y1=Y2
68 IF A$=CHR$(8) THEN X2=X1:Y2=Y1+1:GOSUB 1000:GOSUB 29000:X1=X2:Y1=Y2
69 IF A$=CHR$(2) THEN X2=X1+1:Y2=Y1:GOSUB 1000:GOSUB 29000:X1=X2:Y1=Y2



70 IF A$="I" THEN X2=X1-1:Y2=Y1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT"$":GOSUB 1100:B(X1,Y1)=1:GOSUB 1200:X1=X2:Y1=Y2
80 IF A$="J" THEN X2=X1:Y2=Y1-1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT"$":GOSUB 1100:B(X1,Y1)=1:GOSUB 1200:X1=X2:Y1=Y2
90 IF A$="K" THEN X2=X1:Y2=Y1+1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT"$":GOSUB 1100:B(X1,Y1)=1:GOSUB 1200:X1=X2:Y1=Y2
95 IF A$="M" THEN X2=X1+1:Y2=Y1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT"$":GOSUB 1100:B(X1,Y1)=1:GOSUB 1200:X1=X2:Y1=Y2
100 IF A$="Y" THEN X2=X1-1:Y2=Y1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT" ":GOSUB 1150:B(X1,Y1)=0:GOSUB 1200:X1=X2:Y1=Y2
110 IF A$="G" THEN X2=X1:Y2=Y1-1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT" ":GOSUB 1150:B(X1,Y1)=0:GOSUB 1200:X1=X2:Y1=Y2
120 IF A$="H" THEN X2=X1:Y2=Y1+1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT" ":GOSUB 1150:B(X1,Y1)=0:GOSUB 1200:X1=X2:Y1=Y2
130 IF A$="B" THEN X2=X1+1:Y2=Y1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT" ":GOSUB 1150:B(X1,Y1)=0:GOSUB 1200:X1=X2:Y1=Y2

160 IF A$="R" THEN 300

162 IF A$="F" THEN 30000


172 IF A$="S" THEN 15000
180 IF A$="L" THEN 15100
182 IF A$="C" THEN 15500
184 IF A$="X" THEN 15800

200 GOTO 60

300 X4=10:Y4=40:I1=1:S1=0:H2=0
305 VTAB 20:HTAB 47:PRINT"           ":VTAB 21:HTAB 75:PRINT"   0":VTAB 22:HTAB 75:PRINT"   0"
310 IF B(10,40)=1 THEN B(10,40)=0:VTAB 10:HTAB 40:PRINT"M":BB=BB-1:GOSUB 1200

312 REM IF B(V8,V9)=1 AND G1>0 THEN B(V8,V9)=0:VTAB V8:HTAB V9:PRINT"T":BB=BB-1:GOSUB 1200 

314 IF B(X4,Y4+1)=1 AND B(X4+1,Y4+1)=1 AND B(X4+1,Y4)=1 AND B(X4+1,Y4-1)=1 AND B(X4,Y4-1)=1 AND B(X4-1,Y4-1)=1 AND B(X4-1,Y4)=1 AND B(X4-1,Y4+1)=1 THEN INVERSE:VTAB 20:HTAB 47:PRINT"NO EXIT":NORMAL:GOTO 60


315 VTAB X4:HTAB Y4:PRINT"M"
320 X5=X4:Y5=Y4
330 IF B(X4+1,Y4-1)=0 THEN XX=X4+1:YY=Y4-1:Q=5:F1=1:GOTO 530
340 IF B(X4+1,Y4)=0 THEN XX=X4+1:YY=Y4:Q=4:F1=2:GOTO 530
350 IF B(X4+1,Y4+1)=0 THEN XX=X4+1:YY=Y4+1:Q=6:F1=3:GOTO 530
360 IF B(X4,Y4+1)=0 THEN XX=X4:YY=Y4+1:Q=3:F1=4:GOTO 530
370 IF B(X4-1,Y4+1)=0 THEN XX=X4-1:YY=Y4+1:Q=7:F1=5:GOTO 530
380 IF B(X4-1,Y4)=0 THEN XX=X4-1:YY=Y4:Q=2:F1=6:GOTO 530
390 IF B(X4-1,Y4-1)=0 THEN XX=X4-1:YY=Y4-1:Q=8:F1=7:GOTO 530
395 IF B(X4,Y4-1)=0 THEN XX=X4:YY=Y4-1:Q=1:F1=8:GOTO 530
400 I1=I1-1:IF I1<1 THEN I1=1
410 A7=C(I1):C(I1)=23:H2=H2+1:N1=22:N2=78:GOSUB 900
420 IF A7=1 THEN YY=Y4+1:XX=X4
430 IF A7=4 THEN XX=X4-1:YY=Y4
440 IF A7=3 THEN YY=Y4-1:XX=X4
450 IF A7=2 THEN XX=X4+1:YY=Y4
460 IF A7=5 THEN XX=X4-1:YY=Y4+1
470 IF A7=6 THEN XX=X4-1:YY=Y4-1
480 IF A7=7 THEN XX=X4+1:YY=Y4-1
490 IF A7=8 THEN XX=X4+1:YY=Y4+1
500 GOTO 550
530 IF B(XX,YY)=2 THEN XX=X4:YY=Y4:ON F1 GOTO 340,350,360,370,380,390,395,400
540 C(I1)=Q:I1=I1+1
550 VTAB X4:HTAB Y4:PRINT" ":B(XX,YY)=2 
560 IF XX>19 OR XX<1 OR YY>79 OR YY<1 THEN VTAB X5:HTAB Y5:PRINT" ":GOSUB 27000:S1=0:H2=0:GOTO 650
570 X4=XX:Y4=YY:VTAB X4:HTAB Y4:PRINT"M":VTAB X5:HTAB Y5:PRINT" "
575 IF XX=10 AND YY=40 THEN R1=R1+1 
577 IF R1>8 THEN R1=0:NO=1:INVERSE:VTAB 20:HTAB 47:PRINT"NO EXIT":NORMAL:GOTO 650
580 S1=S1+1:N1=21:N2=78
590 IF S1>9 THEN N2=N2-1
600 IF S1>99 THEN N2=N2-1
610 IF S1>999 THEN N2=N2-1
620 VTAB N1:HTAB N2: PRINT S1
640 GOTO 315

650 INVERSE:VTAB 23:HTAB 1:PRINT"              WAITING                       ":NORMAL

660 FOR I=0 TO 20
670 FOR J=0 TO 80
680 IF B(I,J)<>1 THEN B(I,J)=0
690 NEXT J
700 NEXT I
705 INVERSE:VTAB 23:HTAB 15:PRINT"        ":NORMAL
710 IF NO=1 THEN NO=0:GOTO 60
720 INVERSE:VTAB 20:HTAB 47:PRINT"SHORTCUT":NORMAL
730 X7=10:Y7=40:I2=1
740 IF C(I2)=5 THEN X8=X7+1:Y8=Y7-1
750 IF C(I2)=4 THEN X8=X7+1:Y8=Y7
760 IF C(I2)=6 THEN X8=X7+1:Y8=Y7+1
770 IF C(I2)=3 THEN X8=X7:Y8=Y7+1
780 IF C(I2)=7 THEN X8=X7-1:Y8=Y7+1
790 IF C(I2)=2 THEN X8=X7-1:Y8=Y7
792 IF C(I2)=8 THEN X8=X7-1:Y8=Y7-1 
794 IF C(I2)=1 THEN X8=X7:Y8=Y7-1
796 IF X8>19 OR X8<1 OR Y8>79 OR Y8<1 THEN VTAB X7:HTAB Y7:PRINT" ":VTAB 20:HTAB 47:PRINT"            ":GOTO 60
800 VTAB X8:HTAB Y8:PRINT"M":VTAB X7:HTAB Y7:PRINT" ":X7=X8:Y7=Y8
810 I2=I2+1
880 GOTO 740

900 IF H2>9 THEN N2=N2-1
910 IF H2>99 THEN N2=N2-1
920 IF H2>999 THEN N2=N2-1
930 VTAB N1:HTAB N2: PRINT H2
940 RETURN




1000 IF X2<1 THEN X2=19
1010 IF X2>19 THEN X2=1
1020 IF Y2<1 THEN Y2=79
1030 IF Y2>79 THEN Y2=1
1040 RETURN

1100 IF B(X1,Y1)=0 THEN BB=BB+1
1110 RETURN 

1150 IF B(X1,Y1)=1 THEN BB=BB-1
1160 RETURN

1200 IF BB<0 THEN BB=0
1210 IF BB<10 AND BB>-1 THEN NN1=78
1220 IF BB<100 AND BB>9 THEN NN1=77
1230 IF BB<1000 AND BB>99 THEN NN1=76
1240 IF BB<10000 AND BB>999 THEN NN1=75
1242 VTAB 20:HTAB 75:PRINT"    "
1260 VTAB 20:HTAB NN1:PRINT BB
1270 RETURN

1400 N1=21:N2=78
1410 IF S1>9 THEN N2=N2-1
1420 IF S1>99 THEN N2=N2-1
1430 IF S1>999 THEN N2=N2-1
1440 VTAB N1:HTAB N2: PRINT S1
1450 RETURN


1500 IF X2<4 THEN X2=4
1510 IF X2>16 THEN X2=16
1520 IF Y2<4 THEN Y2=4
1530 IF Y2>76 THEN Y2=76
1540 RETURN


1600 IF X2<7 THEN X2=13
1610 IF X2>13 THEN X2=7
1620 IF Y2<39 THEN Y2=45
1630 IF Y2>45 THEN Y2=39
1640 RETURN


1700 IF XD<1 THEN XD=7
1710 IF XD>7 THEN XD=1
1720 IF YD<1 THEN YD=7
1730 IF YD>7 THEN YD=1
1740 RETURN




7000 HOME:PRINT CHR$(4);"CATALOG"+",D1,S6":END





15000 INVERSE:VTAB 23:HTAB 1:PRINT"                                                 ":VTAB 23:HTAB 1:INPUT"FILENAME : ";F$:NORMAL
15005 INVERSE:VTAB 23:HTAB 50:PRINT"SAVING":NORMAL
15007 IF F$=CHR$(43) THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 60

15009 IF LEN(F$) > 24 THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 15000

15010 ONERR GOTO 22200

15012 PRINT CHR$(4);"OPEN";F$
15020 PRINT CHR$(4);"WRITE";F$ 
15030 FOR I=1 TO 19
15040 FOR J=1 TO 79
15050 PRINT B(I,J)
15060 NEXT J
15070 NEXT I
15072 PRINT CHR$(4);"CLOSE";F$

15074 X9=10:Y9=40:V8=10:V9=38:G1=0:MA=0

15075 M(1)=1:M(2)=2:M(3)=3:M(4)=4:M(5)=5:M(6)=6:M(7)=7:M(8)=8

15076 T$="R  DR  D  DL  L  UL  U  UR "


15081 PRINT CHR$(4);"OPEN";F$+".INDEX"
15082 PRINT CHR$(4);"WRITE";F$+".INDEX"
15083 PRINT X1:PRINT Y1:PRINT X9:PRINT Y9:PRINT V8:PRINT V9:PRINT G1:PRINT M(1):PRINT M(2):PRINT M(3):PRINT M(4):PRINT M(5):PRINT M(6):PRINT M(7):PRINT M(8):PRINT T$:PRINT MA
15084 PRINT CHR$(4);"CLOSE";F$+".INDEX"

15086 PRINT CHR$(4);"OPEN";F$+".BITMAP"
15088 PRINT CHR$(4);"WRITE";F$+".BITMAP" 
15090 FOR I=1 TO 19
15092 FOR J=1 TO 79
15093 PRINT B(I,J);
15094 NEXT J
15095 PRINT
15096 NEXT I
15097 PRINT CHR$(4);"CLOSE";F$+".BITMAP"

15098 INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL
15099 GOTO 60

15100 INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":VTAB 23:HTAB 1:INPUT"FILENAME : ";F$:NORMAL
15105 INVERSE:VTAB 23:HTAB 50:PRINT"LOADING":NORMAL
15106 IF F$=CHR$(43) THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 60

15108 ONERR GOTO 22200

15110 PRINT CHR$(4);"OPEN";F$
15120 PRINT CHR$(4);"READ";F$ 
15130 FOR I=1 TO 19
15140 FOR J=1 TO 79
15150 INPUT B(I,J)
15160 NEXT J
15170 NEXT I
15180 PRINT CHR$(4);"CLOSE";F$
15181 PRINT CHR$(4);"OPEN";F$+".INDEX"
15182 PRINT CHR$(4);"READ";F$+".INDEX"
15183 INPUT X1:INPUT Y1:INPUT X9:INPUT Y9:INPUT V8:INPUT V9:INPUT G1:INPUT M(1):INPUT M(2):INPUT M(3):INPUT M(4):INPUT M(5):INPUT M(6):INPUT M(7):INPUT M(8):INPUT T$:INPUT MA
15184 PRINT CHR$(4);"CLOSE";F$+".INDEX"
15185 INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL
15187 GOSUB 15200

15188 REM IF G1>0 THEN INVERSE:VTAB 23:HTAB 50:PRINT"TARGET MODE     ":NORMAL:VTAB V8:HTAB V9:PRINT"T"

15189 NORMAL:VTAB 20:HTAB 45:PRINT"                     "
15190 LL=1:GOSUB 1200:GOTO 60

15200 BB=0:VTAB 20:HTAB 75:PRINT"    ":VTAB 21:HTAB 75:PRINT"   0":VTAB 22:HTAB 75:PRINT"   0" 
15202 FOR I=1 TO 19
15210 FOR J=1 TO 79
15220 IF B(I,J)=1 THEN VTAB I:HTAB J:PRINT"$":BB=BB+1:GOSUB 1200
15222 IF B(I,J)<>1 THEN VTAB I:HTAB J:PRINT" "
15230 NEXT J
15240 NEXT I
15250 RETURN


15500 NORMAL:VTAB 20:HTAB 45:PRINT"                     ":INVERSE:VTAB 23:HTAB 66:PRINT"             ":NORMAL

15502 FOR I=1 TO 19
15510 FOR J=1 TO 79
15520 VTAB I:HTAB J:PRINT" "
15530 NEXT J
15540 NEXT I

15542 FOR I=0 TO 20
15543 FOR J=0 TO 80
15544 B(I,J)=0
15545 NEXT J
15546 NEXT I

15547 FOR I=0 TO 1510:C(I)=0:NEXT I

15548 BB=0
15549 VTAB 20:HTAB 75:PRINT"   0":VTAB 21:HTAB 75:PRINT"   0":VTAB 22:HTAB 75:PRINT"   0"

15550 IF MK=1 THEN MK=0:RETURN

15560 GOTO 60

15800 HOME
15802 PRINT CHR$(4);"CATALOG"+",D2,S6"
15810 PRINT:PRINT"<PRESS ANY KEY TO BE CONTINUE>":NORMAL:GET CT$
15820 HOME:BB=0
15830 FOR I=1 TO 19
15840 FOR J=1 TO 79
15850 IF B(I,J)=1 THEN VTAB I:HTAB J:PRINT"$":BB=BB+1
15860 NEXT J
15870 NEXT I

15880 IF D2=1 THEN D2=0:RETURN

15990 GOTO 52




22200 Y=PEEK(222)

22210 IF Y=4 THEN INVERSE:VTAB 23:HTAB 50:PRINT"WRITE PROTECTED":NORMAL:GOSUB 22500:GOTO 60
22212 IF Y=7 THEN INVERSE:VTAB 23:HTAB 50:PRINT"VOLUME MISMATCH":NORMAL:GOSUB 22500:GOTO 60
22214 IF Y=8 THEN INVERSE:VTAB 23:HTAB 50:PRINT"I/O ERROR":NORMAL:GOSUB 22500:GOTO 60
22216 IF Y=9 THEN INVERSE:VTAB 23:HTAB 50:PRINT"DISK FULL":NORMAL:GOSUB 22500:GOTO 60
22218 IF Y=10 THEN INVERSE:VTAB 23:HTAB 50:PRINT"FILE LOCKED":NORMAL:GOSUB 22500:GOTO 60
22219 IF Y=11 THEN INVERSE:VTAB 23:HTAB 50:PRINT"SYNTAX ERROR":NORMAL:GOSUB 22500:GOTO 60
22220 IF Y=13 THEN INVERSE:VTAB 23:HTAB 50:PRINT"FILE TYPE MISMATCH":NORMAL:GOSUB 22500:GOTO 60

22298 INVERSE:VTAB 23:HTAB 50:PRINT"FILE NOT FOUND":NORMAL:GOSUB 22500:GOTO 60

22500 FOR I=1 TO 50000
22510 NEXT I

22520 RETURN

27000 S1=S1+1:N1=21:N2=78
27010 IF S1>9 THEN N2=N2-1
27020 IF S1>99 THEN N2=N2-1
27030 IF S1>999 THEN N2=N2-1
27040 VTAB N1:HTAB N2: PRINT S1
27050 RETURN

29000 IF X1=10 AND Y1=40 THEN 29040
29010 IF B(X1,Y1)=1 THEN NORMAL:VTAB X1:HTAB Y1:PRINT"$"
29020 IF B(X1,Y1)=0 THEN NORMAL:VTAB X1:HTAB Y1:PRINT" "
29030 IF X2=10 AND Y2=40 THEN 29050
29040 INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL
 

29050 RETURN


30000 INVERSE:VTAB 23:HTAB 1:PRINT"COMMAND :                                                                     ":VTAB 23:HTAB 50:PRINT"MAZE PAINTER":VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL

30030 IF A$="A" THEN X2=X1:Y2=Y1:GOSUB 31000:GOTO 56000

30032 IF A$="D" THEN X1=10:Y1=42:X2=X1:Y2=Y1:XC=4:YC=4:MK=1:GOSUB 62000:GOSUB 59000:GOTO 58000

30040 IF A$=CHR$(43) THEN MK=0:INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 60

30060 GOTO 30000


31000 NORMAL
31010 IF B(X1,Y1)=1 THEN VTAB X1:HTAB Y1:PRINT"$"
31020 IF B(X1,Y1)=0 THEN VTAB X1:HTAB Y1:PRINT" "
31030 GOSUB 1500:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:X1=X2:Y1=Y2
31040 RETURN



47000 REM IF X1=10 AND Y1=40 THEN 48040
47010 IF D(XC,YC)=1 THEN NORMAL:VTAB X1:HTAB Y1:PRINT"$"
47020 IF D(XC,YC)=0 THEN NORMAL:VTAB X1:HTAB Y1:PRINT" "
47030 REM IF X2=10 AND Y2=40 THEN 48050
47040 INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL

47050 RETURN



48000 IF X1=10 AND Y1=40 THEN 48040
48010 IF B(X1,Y1)=1 THEN NORMAL:VTAB X1:HTAB Y1:PRINT"$"
48020 IF B(X1,Y1)=0 THEN NORMAL:VTAB X1:HTAB Y1:PRINT" "
48030 IF X2=10 AND Y2=40 THEN 48050
48040 INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL
 

48050 RETURN





49000 FOR I=1 TO 19
49010 FOR J=1 TO 79
49020 IF B(I,J)=1 THEN VTAB I:HTAB J:PRINT"$":GOTO 49040
49030 VTAB I:HTAB J:PRINT" "
49040 NEXT J
49050 NEXT I
49060 RETURN


49500 BB=0

49502 FOR I=1 TO 19
49510 FOR J=1 TO 79
49520 IF B(I,J)=1 THEN BB=BB+1
49530 NEXT J
49540 NEXT I

49542 GOSUB 1200

49550 RETURN




56000 AW=1:GOSUB 59800

56001 VTAB 10:HTAB 40:PRINT"M":INVERSE:VTAB X1:HTAB Y1:PRINT"$":NORMAL


56002 INVERSE:VTAB 23:HTAB 1:PRINT"COMMAND :                                                                     ":VTAB 23:HTAB 50:PRINT"ALPHABET":VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL

56066 IF A$=CHR$(25) THEN X2=X1-1:Y2=Y1:GOSUB 1500:GOSUB 48000:NORMAL:VTAB 10:HTAB 40:PRINT"M":X1=X2:Y1=Y2
56067 IF A$=CHR$(7) THEN X2=X1:Y2=Y1-1:GOSUB 1500:GOSUB 48000:NORMAL:VTAB 10:HTAB 40:PRINT"M":X1=X2:Y1=Y2
56068 IF A$=CHR$(8) THEN X2=X1:Y2=Y1+1:GOSUB 1500:GOSUB 48000:NORMAL:VTAB 10:HTAB 40:PRINT"M":X1=X2:Y1=Y2
56069 IF A$=CHR$(2) THEN X2=X1+1:Y2=Y1:GOSUB 1500:GOSUB 48000:NORMAL:VTAB 10:HTAB 40:PRINT"M":X1=X2:Y1=Y2

56070 IF A$=CHR$(43) THEN INVERSE:VTAB X1:HTAB Y1:PRINT"$":NORMAL:VTAB 10:HTAB 40:PRINT"M":INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 30000

56080 IF A$="B" THEN 57000
56082 IF A$="C" THEN 57500

56084 IF A$="L" THEN AW=1:GOSUB 59800


56090 GOTO 56001


57000 REM 

57100 FOR I=1 TO 7
57144 FOR J=1 TO 7
57146 IF D(I,J)=1 THEN NORMAL:VTAB I+X2-4:HTAB J+Y2-4:PRINT"$":B(I+X2-4,J+Y2-4)=1
57147 NEXT J
57148 NEXT I

57149 GOSUB 49500

57150 GOTO 56001


57500 FOR I=1 TO 7
57544 FOR J=1 TO 7
57546 IF D(I,J)=1 THEN NORMAL:VTAB I+X2-4:HTAB J+Y2-4:PRINT" ":B(I+X2-4,J+Y2-4)=0
57547 NEXT J
57548 NEXT I

57550 GOSUB 49500

57560 GOTO 56001
 


58000 INVERSE:VTAB X1:HTAB Y1:PRINT"$":NORMAL

58002 INVERSE:VTAB 23:HTAB 1:PRINT"COMMAND : ":VTAB 23:HTAB 50:PRINT"PATTERN DESIGNER":VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL 

58066 IF A$=CHR$(25) THEN X2=X1-1:Y2=Y1:XD=XC-1:YD=YC:GOSUB 1600:GOSUB 1700:GOSUB 47000:X1=X2:Y1=Y2:XC=XD:YC=YD
58067 IF A$=CHR$(7) THEN X2=X1:Y2=Y1-1:XD=XC:YD=YC-1:GOSUB 1600:GOSUB 1700:GOSUB 47000:X1=X2:Y1=Y2:XC=XD:YC=YD
58068 IF A$=CHR$(8) THEN X2=X1:Y2=Y1+1:XD=XC:YD=YC+1:GOSUB 1600:GOSUB 1700:GOSUB 47000:X1=X2:Y1=Y2:XC=XD:YC=YD
58069 IF A$=CHR$(2) THEN X2=X1+1:Y2=Y1:XD=XC+1:YD=YC:GOSUB 1600:GOSUB 1700:GOSUB 47000:X1=X2:Y1=Y2:XC=XD:YC=YD


58070 IF A$=CHR$(43) THEN GOSUB 61000:INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 30000


58080 IF A$="B" THEN 59100
58082 IF A$="C" THEN 59200

58084 IF A$="S" THEN 59500
58086 IF A$="L" THEN 59800

58088 IF A$="D" THEN GOSUB 60000


58090 GOTO 58000



59000 INVERSE

59010 FOR I=6 TO 14:VTAB I:HTAB 38:PRINT" ":NEXT I
59020 FOR I=6 TO 14:VTAB I:HTAB 46:PRINT" ":NEXT I

59030 FOR J=38 TO 46:VTAB 6:HTAB J:PRINT" ":NEXT J
59040 FOR J=38 TO 46:VTAB 14:HTAB J:PRINT" ":NEXT J

59042 FOR I=1 TO 7
59044 FOR J=1 TO 7
59046 D(I,J)=0
59047 NEXT J
59048 NEXT I

59050 RETURN


59100 D(XC,YC)=1
59110 GOTO 58002


59200 D(XC,YC)=0
59210 GOTO 58002


59500 INVERSE:VTAB 23:HTAB 1:PRINT"                                                 ":VTAB 23:HTAB 1:INPUT"FILENAME : ";F$:NORMAL
59505 INVERSE:VTAB 23:HTAB 50:PRINT"SAVING":NORMAL
59507 IF F$=CHR$(43) THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 58002

59509 IF LEN(F$) > 24 THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 59500

59510 ONERR GOTO 22200

59512 PRINT CHR$(4);"OPEN";F$+".PATTERN"
59520 PRINT CHR$(4);"WRITE";F$+".PATTERN" 
59530 FOR I=1 TO 7
59540 FOR J=1 TO 7
59550 PRINT D(I,J)
59560 NEXT J
59570 NEXT I
59572 PRINT CHR$(4);"CLOSE";F$+".PATTERN"

59598 INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL
59599 GOTO 58002


59800 INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":VTAB 23:HTAB 1:INPUT"FILENAME : ";F$:NORMAL
59805 INVERSE:VTAB 23:HTAB 50:PRINT"LOADING":NORMAL

59806 IF AW=1 AND F$=CHR$(43) THEN AW=0:INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:RETURN

59807 IF F$=CHR$(43) THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 58002

59808 ONERR GOTO 22200

59810 PRINT CHR$(4);"OPEN";F$+".PATTERN"
59820 PRINT CHR$(4);"READ";F$+".PATTERN" 
59830 FOR I=1 TO 7
59840 FOR J=1 TO 7
59850 INPUT D(I,J)
59860 NEXT J
59870 NEXT I
59880 PRINT CHR$(4);"CLOSE";F$+".PATTERN"

59881 IF AW=1 THEN AW=0:INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:RETURN

59882 GOSUB 59900

59883 INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL

59886 GOTO 58000


59900 REM
59902 FOR I=7 TO 13
59910 FOR J=39 TO 45
59920 IF D(I-6,J-38)=1 THEN VTAB I:HTAB J:PRINT"$"
59922 IF D(I-6,J-38)<>1 THEN VTAB I:HTAB J:PRINT" "
59930 NEXT J
59940 NEXT I
59950 RETURN


60000 FOR I=1 TO 7
60044 FOR J=1 TO 7
60046 D(I,J)=0:NORMAL:VTAB I+6:HTAB J+38:PRINT" "
60047 NEXT J
60048 NEXT I

60050 RETURN
 


61000 BB=0
61030 FOR I=1 TO 19
61040 FOR J=1 TO 79
61050 IF B(I,J)=1 THEN VTAB I:HTAB J:PRINT"$":BB=BB+1:GOSUB 1200:GOTO 61060
61052 VTAB I:HTAB J:PRINT" "
61060 NEXT J
61070 NEXT I

61080 GOSUB 59042

61090 RETURN


62000 REM

62102 FOR I=1 TO 19
62110 FOR J=1 TO 79
62120 VTAB I:HTAB J:PRINT" "
62130 NEXT J
62140 NEXT I

62150 RETURN